Jesus · Bible · HTML · CSS · JS · PHP · SVG · Applications

PaperPlane

PaperPlane is a primitive object.

Example

PaperPlane

Instructions

  1. Import
    import org.papervision3d.objects.primitives.PaperPlane;
  2. Declare
    private var object :PaperPlane;
  3. Initialize
    object = new Plane(material, scale);
    ParameterDefaultDescription
    materialnullmaterial properties
    scale0scale factor
  4. Add
    scene.addChild(object);

Code

package
{
    import flash.display.Sprite;
    import flash.events.Event;

    import org.papervision3d.cameras.Camera3D;
    import org.papervision3d.events.InteractiveScene3DEvent;
    import org.papervision3d.materials.ColorMaterial;
    import org.papervision3d.materials.WireframeMaterial;
    import org.papervision3d.materials.special.CompositeMaterial;
    import org.papervision3d.objects.primitives.PaperPlane;
    import org.papervision3d.render.BasicRenderEngine;
    import org.papervision3d.scenes.Scene3D;
    import org.papervision3d.view.Viewport3D;

    public class Papervision3DPaperPlane extends Sprite
    {
        private var scene    :Scene3D;
        private var camera   :Camera3D;
        private var viewport :Viewport3D;
        private var renderer :BasicRenderEngine;
        private var material :CompositeMaterial;
        private var object   :PaperPlane;

        public function Papervision3DPaperPlane()
        {
            scene = new Scene3D();

            camera = new Camera3D();

            viewport                  = new Viewport3D();
            viewport.autoScaleToStage = true;
            viewport.interactive      = true;
            addChild(viewport);

            renderer = new BasicRenderEngine();

            material             = new CompositeMaterial();
            material.doubleSided = true;
            material.interactive = true;
            material.addMaterial(new ColorMaterial(0x000000, 0.5));
            material.addMaterial(new WireframeMaterial(0x000000));

            object = new PaperPlane(material, 4);
            scene.addChild(object);

            object.addEventListener(InteractiveScene3DEvent.OBJECT_OVER, handleObjectOver);
            object.addEventListener(InteractiveScene3DEvent.OBJECT_OUT, handleObjectOut);
            object.addEventListener(InteractiveScene3DEvent.OBJECT_PRESS, handleObjectPress);

            addEventListener(Event.ENTER_FRAME, handleEnterFrame);
        }

        private function handleEnterFrame(e:Event):void
        {
            object.roll(-1);
            object.yaw(1);

            renderer.renderScene(scene, camera, viewport);
        }

        private function handleObjectOver(e:InteractiveScene3DEvent):void
        {
            viewport.containerSprite.buttonMode = true;
        }

        private function handleObjectOut(e:InteractiveScene3DEvent):void
        {
            viewport.containerSprite.buttonMode = false;
        }

        private function handleObjectPress(e:InteractiveScene3DEvent):void
        {
            var color :uint = Math.random() * 0xFFFFFF;

            material.removeAllMaterials();
            material.addMaterial(new ColorMaterial(color, 0.5));
            material.addMaterial(new WireframeMaterial(color));
        }
    }
}

Download

HomeMenu