Skew

Skew is a modifier that skews an object.

1. Import stack, modifier, 3D engine library

   import com.as3dmod.ModifierStack;
   import com.as3dmod.modifiers.Skew;
   import com.as3dmod.plugins.pv3d.LibraryPv3d;

2. Declare

   private var stack :ModifierStack;

3. Initialize

   stack = new ModifierStack(lib3d, mesh);

   Parameter	Default	Description
   lib3d	NONE	3D engine library
   mesh	NONE	3D object

4. Add

   stack.addModifier(new Skew(f));

   Parameter	Default	Description
   f	0	force skew

5. Apply

   stack.apply();

package
{
    import com.as3dmod.ModifierStack;
    import com.as3dmod.modifiers.Skew;
    import com.as3dmod.plugins.pv3d.LibraryPv3d;

    import flash.events.Event;

    import org.papervision3d.materials.WireframeMaterial;
    import org.papervision3d.objects.primitives.Plane;
    import org.papervision3d.view.BasicView;

    public class AS3DmodSkew extends BasicView
    {
        private var object :Plane;
        private var stack  :ModifierStack;

        public function AS3DmodSkew()
        {
            super();

            var material :WireframeMaterial = new WireframeMaterial(0x000000);
            material.doubleSided = true;

            object = new Plane(material, 500, 500, 10, 10);
            scene.addChild(object);

            stack = new ModifierStack(new LibraryPv3d(), object);
            stack.addModifier(new Skew(200));
            stack.apply();

            startRendering();
        }

        protected override function onRenderTick(e:Event=null):void
        {
            object.yaw(1);

            super.onRenderTick(e);
        }
    }
}

Download