BitmapMaterial

BitmapMaterial is an embeded bitmap file used as a texture.

1. Import

   import org.papervision3d.materials.BitmapMaterial;

2. Declare

   private var material :BitmapMaterial;

3. Initialize

   material = new BitmapMaterial(asset, precise);

   Parameter	Default	Description
   asset	null	bitmap data
   precise	false	fix distortion

package
{
    import flash.display.Bitmap;
    import flash.display.Sprite;
    import flash.events.Event;

    import org.papervision3d.cameras.Camera3D;
    import org.papervision3d.materials.BitmapMaterial;
    import org.papervision3d.objects.primitives.Plane;
    import org.papervision3d.render.BasicRenderEngine;
    import org.papervision3d.scenes.Scene3D;
    import org.papervision3d.view.Viewport3D;

    public class Papervision3DBitmapMaterial extends Sprite
    {
        [Embed(source="HappyFace.jpg")]
        private var Asset :Class;

        private var scene    :Scene3D;
        private var camera   :Camera3D;
        private var viewport :Viewport3D;
        private var renderer :BasicRenderEngine;
        private var material :BitmapMaterial;
        private var object   :Plane;

        public function Papervision3DBitmapMaterial()
        {
            scene = new Scene3D();

            camera = new Camera3D();

            viewport                  = new Viewport3D();
            viewport.autoScaleToStage = true;
            addChild(viewport);

            renderer = new BasicRenderEngine();

            var bitmap :Bitmap = new Asset();

            material             = new BitmapMaterial(bitmap.bitmapData, true);
            material.doubleSided = true;

            object = new Plane(material);
            scene.addChild(object);

            addEventListener(Event.ENTER_FRAME, handleEnterFrame);
        }

        private function handleEnterFrame(e:Event):void
        {
            object.yaw(1);

            renderer.renderScene(scene, camera, viewport);
        }
    }
}

Download