WireframeMaterial

WireframeMaterial is a triangle outline used as a texture.

1. Import

   import org.papervision3d.materials.WireframeMaterial;

2. Declare

   private var material :WireframeMaterial;

3. Initialize

   material = new WireframeMaterial(color, alpha, thickness);

   Parameter	Default	Description
   color	0xff00ff	line color
   alpha	1	line alpha
   thickness	0	line thickness

package
{
    import flash.display.Sprite;
    import flash.events.Event;

    import org.papervision3d.cameras.Camera3D;
    import org.papervision3d.materials.WireframeMaterial;
    import org.papervision3d.objects.primitives.Plane;
    import org.papervision3d.render.BasicRenderEngine;
    import org.papervision3d.scenes.Scene3D;
    import org.papervision3d.view.Viewport3D;

    public class Papervision3DWireframeMaterial extends Sprite
    {
        private var scene    :Scene3D;
        private var camera   :Camera3D;
        private var viewport :Viewport3D;
        private var renderer :BasicRenderEngine;
        private var material :WireframeMaterial;
        private var object   :Plane;

        public function Papervision3DWireframeMaterial()
        {
            scene = new Scene3D();

            camera = new Camera3D();

            viewport                  = new Viewport3D();
            viewport.autoScaleToStage = true;
            addChild(viewport);

            renderer = new BasicRenderEngine();

            material             = new WireframeMaterial(0x000000);
            material.doubleSided = true;

            object = new Plane(material);
            scene.addChild(object);

            addEventListener(Event.ENTER_FRAME, handleEnterFrame);
        }

        private function handleEnterFrame(e:Event):void
        {
            object.yaw(1);

            renderer.renderScene(scene, camera, viewport);
        }
    }
}

Download